COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	TITLE DSKOPS
C00004 ENDMK
C⊗;
TITLE DSKOPS

A←1
B←2
C←3
D←4
E←5
T←6
TT←7

P←17

GO:	RESET
	MOVE P,[-100,,PDL-1]
	MOVSI A,377001
	SETPR2 A,
	JRST 4,.
	MOVEI T,0
	MOVSI A,-NSYMS
LOOP:	MOVE B,NAMTAB(A)
	MOVEI C,0
	MOVEI D,B
	.SYML D,
	JRST 4,.
	MOVE D,400000(D)
	MOVEM D,VALTAB(A)
	ADD T,D
	AOBJN A,LOOP
	OUTSTR [ASCIZ /NUMBER OF READ DATA OPS = /]
	MOVE A,NDRDOP
	PUSHJ P,PRINT
	OUTSTR [ASCIZ /NUMBER OF WRITE DATA OPS = /]
	MOVE A,NDWDOP
	PUSHJ P,PRINT
	OUTSTR [ASCIZ /NUMBER OF READ RETRIEVAL OPS = /]
	MOVE A,NDRROP
	PUSHJ P,PRINT
	OUTSTR [ASCIZ /NUMBER OF WRITE RETRIEVAL OPS = /]
	MOVE A,NDWROP
	PUSHJ P,PRINT
	EXIT

PRINT:	PUSH P,A
	PUSHJ P,DECOUT
	OUTSTR [ASCIZ /  /]
	POP P,A
	IMULI A,=100
	IDIV A,T
	PUSHJ P,DECOUT
	OUTSTR [ASCIZ /%
/]
	POPJ P,

DECOUT:	IDIVI A,=10
	JUMPE A,DECOU1
	HRLM B,(P)
	PUSHJ P,DECOUT
	HLRZ B,(P)
DECOU1:	ADDI B,"0"
	OUTCHR B
	POPJ P,

NAMTAB:	RADIX50 0,NDRDOP
	RADIX50 0,NDWDOP
	RADIX50 0,NDRROP
	RADIX50 0,NDWROP
NSYMS←←.-NAMTAB

VALTAB::
NDRDOP:	0
NDWDOP:	0
NDRROP:	0
NDWROP:	0

PDL:	BLOCK 100
	END GO